A user-friendly SPARQL query editor built on the popular YASGUI editor, it provides context-aware autocomplete for classes and predicates based on the content of the endpoints, as well as query examples.

Use it directly for any endpoint at sib-swiss.github.io/sparql-editor.

The editor retrieves metadata about the endpoints by directly querying them, or searching in the SPARQL service description. So all that is needed is to generate and upload some metadata to each endpoints, and it works on top of any triplestore without configuration needed. Reducing the need for complex infrastructure, while making your SPARQL endpoints easier to query for users and machines.

You can also redeploy it for a specific endpoint, or set of endpoints using the standard web component documented below,

🪄 Features

• ✨ Autocomplete possibilities for properties and classes are automatically pulled from the endpoints based on the VoID description present in the triplestore. The suggested properties are contextually filtered based on the class of the subject at the cursor's position, and are aware of SERVICE clauses, ensuring relevant autocompletion even in federated queries. Checkout the void-generator project to automatically generate VoID description for your endpoint.

  Click here to see the SPARQL query used to retrieve the VoID description.

  PREFIX void: <http://rdfs.org/ns/void#>
  PREFIX void-ext: <http://ldf.fi/void-ext#>
  SELECT DISTINCT ?subjectClass ?prop ?objectClass ?objectDatatype
  WHERE {
      {
          ?cp void:class ?subjectClass ;
              void:propertyPartition ?pp .
          ?pp void:property ?prop .
          OPTIONAL {
              {
                  ?pp  void:classPartition [ void:class ?objectClass ] .
              } UNION {
                  ?pp void-ext:datatypePartition [ void-ext:datatype ?objectDatatype ] .
              }
          }
      } UNION {
          ?linkset void:subjectsTarget ?subjectClass ;
              void:linkPredicate ?prop ;
              void:objectsTarget ?objectClass .
      }
  }

• 📜 Example SPARQL queries defined using the SHACL ontology are automatically pulled from the endpoint. Checkout the sparql-examples project for more details.

  Click here to see the SPARQL query used to retrieve the example queries.

  PREFIX sh: <http://www.w3.org/ns/shacl#>
  PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
  SELECT DISTINCT ?sq ?comment ?query
  WHERE {
      ?sq a sh:SPARQLExecutable ;
          rdfs:comment ?comment ;
          sh:select|sh:ask|sh:construct|sh:describe ?query .
  } ORDER BY ?sq

• 🏷️ Prefixes are automatically pulled from the endpoint using their definition defined with the SHACL ontology (sh:prefix/sh:namespace).

  Click here to see the SPARQL query used to retrieve the prefixes/namespaces.

  PREFIX sh: <http://www.w3.org/ns/shacl#>
  SELECT DISTINCT ?prefix ?namespace
  WHERE { [] sh:namespace ?namespace ; sh:prefix ?prefix }
  ORDER BY ?prefix

• 🗺️ Overview of classes using the VoID description.